bnmbertsurhetertertertertertertertpdf'tdfg

hjkhghopjkertteerterterterertertrtoirh bnmbertsurhetertertertertertertertpdf'tdfg

/*======================================================================*//**
* 
* 3PCPG
* 
* @author	Copyright (c) 2008 muraken[undefined™(http://www.undefined.nu)]
* @version	1.0.0
* 
*//*=======================================================================*/
package  display{
	import caurina.transitions.Tweener;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.filters.BlurFilter;

public class Opening extends Sprite{
		private var logoArray:Array = new Array();
		private var _blur:BlurFilter;
		private var isLoading:Boolean = true;
		private var tweenObj:Object = { rotation:500, blur:20 };
		
		public function Opening() {
			//Blurフィルタを作成
			_blur = new BlurFilter(20, 20, 2);
			//ロゴのパーツを元の位置を記録してから一箇所にまとめる
			for (var i:int = 0; i < 5; i++) {
				var _mc:MovieClip = this["l"+i];
				logoArray.push( { mc:_mc, x:_mc.x, y:_mc.y } );
				_mc.x = 0;
			}
			//フィルタを適用
			filters = [_blur];
			addEventListener(Event.ENTER_FRAME, _enterframe);
		}
		public function start():void {
			isLoading = false;
			Tweener.addTween(tweenObj, { rotation:0, blur:0, time:0.6, transition:"easeOutBack", onComplete:end } );
		}
		private function _enterframe(e:Event):void {
			if (isLoading) {
				//Loading中は回転し続ける
				rotation += 40;
			}else {
				//Loadingが終わったらTweenerをしようしたtweenObjのrotationの値に合わせて徐々に止まる。
				rotation = tweenObj.rotation;
				_blur.blurX = _blur.blurY = tweenObj.blur;
				filters = [_blur];
			}
		}
		private function end():void {
			//フィルタを解除
			filters = [];
			rotation = 0;
			removeEventListener(Event.ENTER_FRAME, _enterframe);
			//ロゴのパーツを元の位置に。
			for each(var _obj:Object in logoArray) {
				var _mc:MovieClip = _obj.mc;
				Tweener.addTween(_mc, { x:_obj.x, y:_obj.y, time:0.5, transition:"easeInExpo" } );
			}
			//ロゴが小さく消えていく
			Tweener.addTween(this, { scaleX:0, scaleY:0, time:0.5,delay:0.8, transition:"easeInBack", onComplete:goDispath} );
		}
		private function goDispath():void {
			//Event.COMPLETEを発行
			dispatchEvent(new Event(Event.COMPLETE));
		}
	}
	
}